Electrónica Circuitos electrónicos e información técnica

Monitor del ritmo cardiaco usando el 8051

Este artículo es acerca de un monitor del ritmo cardiaco muy sencillo utilizando el microprocesador 8051. Al igual que los anteriores proyectos con este microprocesador, el AT89S51 es el microcontrolador utilizado aquí. El dispositivo detecta el ritmo cardíaco de la punta de los dedos utilizando el método de reflexión IR y lo muestra en una pantalla de tres dígitos de siete segmentos en latidos por minuto. El circuito tiene una precisión de 4 latidos por minuto y es muy fácil de usar. En términos médicos, la técnica utilizada aquí para la detección de la frecuencia cardíaca se llama fotopletismografía.

Fotopletismografía

Fotopletismografía es el proceso de estimación ópticamente la medición volumétrica de un órgano. La oximetría de pulso, monitoreo cardiovascular, la detección de la respiración, control de la frecuencia cardiaca, etc son algunos usos comunes de fotopletismografía. Vamos a echar un vistazo a la aplicación de fotopletismografía en el monitoreo de la frecuencia cardíaca de la punta del dedo. Cuando el corazón se expande (diástole) el volumen de sangre en la punta de los dedos aumenta y cuando el corazón se contrae (sístole) el volumen de sangre dentro de la punta del dedo disminuye. La pulsación resultante del volumen de sangre dentro de la punta del dedo es directamente proporcional a la frecuencia cardiaca y si pudiera de alguna forma contar el número de pulsos en un minuto, ese es el ritmo cardíaco en latidos por minuto (lpm). Para esto un transmisor y receptor de infrarrojos se coloca en estrecho contacto con la punta del dedo. Cuando el corazón late, el volumen de las células de la sangre bajo los aumentos de sensores y esto refleja las ondas más IR y sensor.

Como funciona el pulsómetro

El LTH1550-01 foto Interruptor forma aquí el sensor fotopletismográfica. El LTH1550-01 es simplemente opto acplador formado por un diodo IR y un fototransistor dentro de un ancapsulado. La parte delantera del diodo IR y fototransistor están expuestos y las partes restantes están bien aisladas. Cuando se coloca la punta del dedo sobre el sensor de la pulsación volumétrica del volumen de sangre dentro de la punta del dedo debido a latido del corazón varía la intensidad del haz reflejado y esta variación en la intensidad está de acuerdo con los latidos del corazón.

Cuando más luz incida sobre el fototransistor, aumenta su corriente de colector y así su tensión de colector disminuye. Cuando hay menos luz sobre el fototransistor, se reduce su corriente de colector y así su tensión de colector disminuye. Esta variación en la tensión de colector será proporcional a la frecuencia cardíaca. Cualquier forma en que esta variación de la tensión es tan débil y etapas de acondicionamiento de señales adicionales son necesarios para convertirlo en una forma reconocible para esto se utiliza el microcontrolador.

La siguiente parte del circuito consiste en dos filtros de paso bajo activos utilizando opamp LM324. El LM324 es un amplificador operacional cuádruple que puede ser operado desde un único suministro de corriente. Resistor R23, R17 y el capacitor C5 establece la ganancia y la frecuencia de corte del primer filtro. Con los valores de los componentes indicados, la ganancia será de 101 y la frecuencia de corte que será de 2,5 Hz. La ganancia y la frecuencia de corte se determinan con las siguientes ecuaciones :

Ganancia de tensión Av = 1 + (R17 / R23)
Frecuencia de corte Fc = 1 / (2p * R17 * C5)

A continuación el programa para el microcontrolador

ORG 000H                   // origin
MOV DPTR,#LUT              // moves starting address of LUT to DPTR
MOV P1,#00000000B          // sets P1 as output port
MOV P0,#00000000B          // sets P0 as output port
MAIN: MOV R6,#230D         // loads register R6 with 230D
      SETB P3.5            // sets P3.5 as input port
      MOV TMOD,#01100001B  // Sets Timer1 as Mode2 counter & Timer0 as Mode1 timer
      MOV TL1,#00000000B   // loads TL1 with initial value
      MOV TH1,#00000000B   // loads TH1 with initial value
      SETB TR1             // starts timer(counter) 1
BACK: MOV TH0,#00000000B   // loads initial value to TH0
      MOV TL0,#00000000B   // loads initial value to TL0
      SETB TR0             // starts timer 0
HERE: JNB TF0,HERE         // checks for Timer 0 roll over
      CLR TR0              // stops Timer0
      CLR TF0              // clears Timer Flag 0
      DJNZ R6,BACK
      CLR TR1              // stops Timer(counter)1
      CLR TF0              // clears Timer Flag 0
      CLR TF1              // clears Timer Flag 1
      ACALL DLOOP          // Calls subroutine DLOOP for displaying the count
      SJMP MAIN            // jumps back to the main loop
DLOOP: MOV R5,#252D
BACK1: MOV A,TL1           // loads the current count to the accumulator
       MOV B,#4D           // loads register B with 4D
       MUL AB              // Multiplies the TL1 count with 4
       MOV B,#100D         // loads register B with 100D
       DIV AB              // isolates first digit of the count
       SETB P1.0           // display driver transistor Q1 ON
       ACALL DISPLAY       // converts 1st digit to 7seg pattern
       MOV P0,A            // puts the pattern to port 0
       ACALL DELAY
       ACALL DELAY
       MOV A,B
       MOV B,#10D
       DIV AB              // isolates the second digit of the count
       CLR P1.0            // display driver transistor Q1 OFF
       SETB P1.1           // display driver transistor Q2 ON
       ACALL DISPLAY       // converts the 2nd digit to 7seg pattern
       MOV P0,A
       ACALL DELAY
       ACALL DELAY
       MOV A,B             // moves the last digit of the count to accumulator
       CLR P1.1            // display driver transistor Q2 OFF
       SETB P1.2           // display driver transistor Q3 ON
       ACALL DISPLAY       // converts 3rd digit to 7seg pattern
       MOV P0,A            // puts the pattern to port 0
       ACALL DELAY         // calls 1ms delay
       ACALL DELAY
       CLR P1.2
       DJNZ R5,BACK1       // repeats the subroutine DLOOP 100 times
       MOV P0,#11111111B
       RET

DELAY: MOV R7,#250D        // 1ms delay
 DEL1: DJNZ R7,DEL1
       RET

DISPLAY: MOVC A,@A+DPTR    // gets 7seg digit drive pattern for current value in A
         CPL A
         RET
LUT: DB 3FH                // LUT starts here
     DB 06H
     DB 5BH
     DB 4FH
     DB 66H
     DB 6DH
     DB 7DH
     DB 07H
     DB 7FH
     DB 6FH
END


Monitor del ritmo cardiaco usando el 8051

Lista de componentes

Capacitores:
C1, C2: 33 pF. cerámicos
C3: 10 µF. electrolítico
C4, C6: 1 µF. electrolíticos
C5, C7: 0.1 µF. cerámicos
Semiconductores:
IC1: LM324.
IC2: AT89S51
X1: 11.0592 MHz.
D4: Led color rojo.
Q1, Q2, Q3: 2N2222
Q4: LTH1550-01 optoacoplador.
DS1, DS2, DS3: Display de 7 segmentos con ánodo común.
Resistores:
R1, R2, R3, R4, R5, R6, R7, R8, R9,R11, R12, R13: 100Ω
R10, R21, R22: 1KΩ
R14, R23: 6.8KΩ
R15: 33KΩ
R16, R19: 68KΩ
R17, R18: 680KΩ
R20: 15KΩ
VR1: (En diagrama original R14): 470Ω, Preset
Otros:
B1: fuente de alimentación de 5 voltios.

Fuente original (en inglés: Heart rate monitor using 8051
Fragmento del texto original en inglés:
This article is about a simple heart rate monitor using 8051 microcontroller. Like the previous 8051 projects, AT89S51 is the microcontroller used here. The device senses the heart rate from the finger tip using IR reflection method and displays it on a three digit seven segment display in beats per minute. The circuit has an accuracy of 4 beats per minute and it is very easy to use. In medical terms, the technique used here for sensing heart rate is called photoplethysmography.

Tabletas de circuito impreso
Este circuito no cuenta con tableta de circuito impreso.


De interés

Les agradeceria que toda consulta se haga a través de los Foros Electrónica y Electricidad, ya que en ocasiones me es imposible atenderlas con prontitud, y en el foro, alguien puede hacerlo antes que alguno de los editores del sitio. De antemano, gracias.

Circuitos Impresos: Sitio en el cual te diseñan el circuito impreso, lo que tienes que hacer es registrarte y escribir un post en el cual describes el circuito y colocas el diagrama o la URL donde se encuentra. únicamente desarrollar circuitos no muy complejo, dado que es un servicio gratuito.

Curso básico de electrónica: Estimados amigos, es un gusto para nosotros poner al alcance de ustedes este modesto curso de electrónica, con esto queremos hacer realidad lo que tanto nos han pedido. Busca el vínculo en el índice.

Electrónica molecular: A partir de la fecha ( 26/04/2008), hemos creado la sección, para tenerte al tanto sobre las noticias de esta rama de la ciencia electrónica.

NOTA: Los circuitos aquí publicados, en su mayoría no han sido probados físicamente, el buen funcionamiento o no de los mismos, es responsabilidad del ensamblador.

Robótica

Robótica, la robótica en su forma más simple
Robótica: Es la rama de la tecnología en la cual se diseñan máquinas que intentan emular las acciones ejecutadas por el ser humano. De hecho, los robots ya son usados para llevar a cabo tareas extremedamente pesadas para una persona, un ejemplo es el montaje de partes de automóviles, camiones, etc.

Circuitos Impresos

Todo circuito electrónico necesita un medio para ensamblarlo, esta es la función de los circuitos impresos ( PCB ). Originalmente vienen en placas vírgenes de baquelita o fibra de vidrio y una capa delgada de cobre en el cual se plasma o diseña el circuito basado en el diagrama o esquema del circuito.